mkinitrd-6.1.5/isolinux/graphics.inc

;; $Id: graphics.inc,v 1.1 2007-09-01 22:44:04 niro Exp $
;; -----------------------------------------------------------------------
;;   
;;   Copyright 1994-2002 H. Peter Anvin - All Rights Reserved
;;
;;   This program is free software; you can redistribute it and/or modify
;;   it under the terms of the GNU General Public License as published by
;;   the Free Software Foundation, Inc., 53 Temple Place Ste 330,
;;   Boston MA 02111-1307, USA; either version 2 of the License, or
;;   (at your option) any later version; incorporated herein by reference.
;;
;; -----------------------------------------------------------------------

; ----------------------------------------------------------------------------
;  VGA splash screen code
; ----------------------------------------------------------------------------

;
; vgadisplayfile:
;	Display a graphical splash screen.
;
; Input:
;
; SI	= cluster/socket pointer
;
		section .text

vgadisplayfile:
		mov [VGACluster],si
		push es

		; This is a cheap and easy way to make sure the screen is
		; cleared in case we were in graphics mode already
		call vgaclearmode
		call vgasetmode
		jnz .error_nz

.graphalready:
		mov ax,xfer_buf_seg		; Use as temporary storage
		mov es,ax
		mov fs,ax

		call vgagetchunk		; Get the first chunk

		; The header WILL be in the first chunk.
		cmp dword [es:xbs_vgabuf],0x1413f33d	; Magic number
.error_nz:	jne .error
		mov ax,[es:xbs_vgabuf+4]
		mov [GraphXSize],ax

		mov dx,xbs_vgabuf+8		; Color map offset
		mov ax,1012h			; Set RGB registers
		xor bx,bx			; First register number
		mov cx,16			; 16 registers
		int 10h
	
.movecursor:
		mov ax,[es:xbs_vgabuf+6]	; Number of pixel rows
		mov dx,[VGAFontSize]
		add ax,dx
		dec ax
		div dl
		xor dx,dx			; Set column to 0
		cmp al,[VidRows]
		jb .rowsok
		mov al,[VidRows]
		dec al
.rowsok:
		mov dh,al
		mov ah,2
		xor bx,bx
		int 10h				; Set cursor below image

		mov cx,[es:xbs_vgabuf+6]	; Number of graphics rows

		mov si,xbs_vgabuf+8+3*16	; Beginning of pixel data
		mov word [VGAPos],0

.drawpixelrow:
		push cx
		mov cx,[GraphXSize]
		mov di,xbs_vgatmpbuf		; Row buffer
		call rledecode			; Decode one row
		push si
		mov si,xbs_vgatmpbuf
		mov di,si
		add di,[GraphXSize]
		mov cx,640/4
		xor eax,eax
		rep stosd			; Clear rest of row
		mov di,0A000h			; VGA segment
		mov es,di
		mov di,[VGAPos]
		mov bp,640
		call packedpixel2vga
		add word [VGAPos],byte 80	; Advance to next pixel row
		push fs
		pop es
		pop si
		pop cx
		loop .drawpixelrow

.error:
		pop es
		ret

;
; rledecode:
;	Decode a pixel row in RLE16 format.
;
; FS:SI	-> input
; CX -> pixel count
; ES:DI -> output (packed pixel)
;
rledecode:
		shl esi,1		; Nybble pointer
		xor dl,dl		; Last pixel
.loop:
		call .getnybble
		cmp al,dl
		je .run			; Start of run sequence
		stosb
		mov dl,al
		dec cx
		jnz .loop
.done:
		shr esi,1
		adc si,byte 0
		ret
.run:
		xor bx,bx
		call .getnybble
		and al,al
		jz .longrun
		mov bl,al
.dorun:
		push cx
		mov cx,bx
		mov al,dl
		rep stosb
		pop cx
		sub cx,bx
		ja .loop
		jmp short .done
.longrun:
		call .getnybble
		mov ah,al
		call .getnybble
		shl al,4
		or al,ah
		mov bl,al
		add bx,16
		jmp short .dorun
.getnybble:
		shr esi,1
		fs lodsb
		jc .high
		dec si
		and al,0Fh
		stc
		rcl esi,1
		ret
.high:
		shr al,4
		cmp si,xbs_vgabuf+trackbufsize	; Chunk overrun
		jb .nonewchunk
		call vgagetchunk
		mov si,xbs_vgabuf		; Start at beginning of buffer
.nonewchunk:
		shl esi,1
		ret

;
; vgagetchunk:
;	Get a new trackbufsize chunk of VGA image data
;
; On input, ES is assumed to point to the buffer segment.
;
vgagetchunk:
		pushad
		mov si,[VGACluster]
		and si,si
		jz .eof				; EOF overrun, not much to do...

		mov cx,[BufSafe]		; One trackbuf worth of data
		mov bx,xbs_vgabuf
		call getfssec

		jnc .noteof
		xor si,si
.noteof:	mov [VGACluster],si

.eof:		popad
		ret

;
; packedpixel2vga:
;	Convert packed-pixel to VGA bitplanes
;
; FS:SI -> packed pixel string
; BP    -> pixel count (multiple of 8)
; ES:DI -> output
;
packedpixel2vga:
		mov dx,3C4h	; VGA Sequencer Register select port
		mov al,2	; Sequencer mask
		out dx,al	; Select the sequencer mask
		inc dx		; VGA Sequencer Register data port
		mov al,1
		mov bl,al
.planeloop:
		pusha
		out dx,al
.loop1:
		mov cx,8
.loop2:
		xchg cx,bx
		fs lodsb
		shr al,cl
		rcl ch,1	; VGA is bigendian.  Sigh.
		xchg cx,bx
		loop .loop2
		mov al,bh
		stosb
		sub bp,byte 8
		ja .loop1
		popa
		inc bl
		shl al,1
		cmp bl,4
		jbe .planeloop
		ret

;
; vgasetmode:
;	Enable VGA graphics, if possible; return ZF=1 on success
;	DS must be set to the base segment; ES is set to DS.
;
vgasetmode:
		push ds
		pop es
		mov ax,1A00h		; Get video card and monitor
		xor bx,bx
		int 10h
		sub bl, 7		; BL=07h and BL=08h OK
		cmp bl, 1
		ja .error		; ZF=0
;		mov bx,TextColorReg
;		mov dx,1009h		; Read color registers
;		int 10h
		mov ax,0012h		; Set mode = 640x480 VGA 16 colors
		int 10h
		mov dx,linear_color
		mov ax,1002h		; Write color registers
		int 10h
		mov [UsingVGA], byte 1

		call use_font		; Set graphics font/data
		mov byte [ScrollAttribute], 00h

		xor ax,ax		; Set ZF
.error:
		ret

;
; vgaclearmode:
;	Disable VGA graphics.  It is not safe to assume any value
;	for DS or ES.
;
vgaclearmode:
		push ds
		push es
		pushad
		mov ax,cs
		mov ds,ax
		mov es,ax
		cmp [UsingVGA], byte 1
		jne .done
		mov ax,0003h		; Return to normal video mode
		int 10h
;		mov dx,TextColorReg	; Restore color registers
;		mov ax,1002h
;		int 10h
		mov [UsingVGA], byte 0

		call use_font		; Restore text font/data
		mov byte [ScrollAttribute], 07h
.done:
		popad
		pop es
		pop ds
		ret

;
; vgashowcursor/vgahidecursor:
;	If VGA graphics is enabled, draw a cursor/clear a cursor
;
vgashowcursor:
		pushad
		mov al,'_'
		jmp short vgacursorcommon
vgahidecursor:
		pushad
		mov al,' '
vgacursorcommon:
		cmp [UsingVGA], byte 1
		jne .done
		mov ah,09h
		mov bx,0007h
		mov cx,1
		int 10h
.done:
		popad
		ret


		section .data
		; Map colors to consecutive DAC registers
linear_color	db 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 0
UsingVGA	db 0

		section .latebss
		alignb 2
GraphXSize	resw 1			; Width of splash screen file
VGAPos		resw 1			; Pointer into VGA memory
VGACluster	resw 1			; Cluster pointer for VGA image file
VGAFilePtr	resw 1			; Pointer into VGAFileBuf
TextColorReg	resb 17			; VGA color registers for text mode
%if IS_SYSLINUX
VGAFileBuf	resb FILENAME_MAX+2	; Unmangled VGA image name
%else
VGAFileBuf	resb FILENAME_MAX	; Unmangled VGA image name
%endif
VGAFileBufEnd	equ $
VGAFileMBuf	resb FILENAME_MAX	; Mangled VGA image name

1	;; $Id: graphics.inc,v 1.1 2007-09-01 22:44:04 niro Exp $
2	;; -----------------------------------------------------------------------
3	;;
4	;; Copyright 1994-2002 H. Peter Anvin - All Rights Reserved
5	;;
6	;; This program is free software; you can redistribute it and/or modify
7	;; it under the terms of the GNU General Public License as published by
8	;; the Free Software Foundation, Inc., 53 Temple Place Ste 330,
9	;; Boston MA 02111-1307, USA; either version 2 of the License, or
10	;; (at your option) any later version; incorporated herein by reference.
11	;;
12	;; -----------------------------------------------------------------------
13
14	; ----------------------------------------------------------------------------
15	; VGA splash screen code
16	; ----------------------------------------------------------------------------
17
18	;
19	; vgadisplayfile:
20	; Display a graphical splash screen.
21	;
22	; Input:
23	;
24	; SI = cluster/socket pointer
25	;
26	section .text
27
28	vgadisplayfile:
29	mov [VGACluster],si
30	push es
31
32	; This is a cheap and easy way to make sure the screen is
33	; cleared in case we were in graphics mode already
34	call vgaclearmode
35	call vgasetmode
36	jnz .error_nz
37
38	.graphalready:
39	mov ax,xfer_buf_seg ; Use as temporary storage
40	mov es,ax
41	mov fs,ax
42
43	call vgagetchunk ; Get the first chunk
44
45	; The header WILL be in the first chunk.
46	cmp dword [es:xbs_vgabuf],0x1413f33d ; Magic number
47	.error_nz: jne .error
48	mov ax,[es:xbs_vgabuf+4]
49	mov [GraphXSize],ax
50
51	mov dx,xbs_vgabuf+8 ; Color map offset
52	mov ax,1012h ; Set RGB registers
53	xor bx,bx ; First register number
54	mov cx,16 ; 16 registers
55	int 10h
56
57	.movecursor:
58	mov ax,[es:xbs_vgabuf+6] ; Number of pixel rows
59	mov dx,[VGAFontSize]
60	add ax,dx
61	dec ax
62	div dl
63	xor dx,dx ; Set column to 0
64	cmp al,[VidRows]
65	jb .rowsok
66	mov al,[VidRows]
67	dec al
68	.rowsok:
69	mov dh,al
70	mov ah,2
71	xor bx,bx
72	int 10h ; Set cursor below image
73
74	mov cx,[es:xbs_vgabuf+6] ; Number of graphics rows
75
76	mov si,xbs_vgabuf+8+3*16 ; Beginning of pixel data
77	mov word [VGAPos],0
78
79	.drawpixelrow:
80	push cx
81	mov cx,[GraphXSize]
82	mov di,xbs_vgatmpbuf ; Row buffer
83	call rledecode ; Decode one row
84	push si
85	mov si,xbs_vgatmpbuf
86	mov di,si
87	add di,[GraphXSize]
88	mov cx,640/4
89	xor eax,eax
90	rep stosd ; Clear rest of row
91	mov di,0A000h ; VGA segment
92	mov es,di
93	mov di,[VGAPos]
94	mov bp,640
95	call packedpixel2vga
96	add word [VGAPos],byte 80 ; Advance to next pixel row
97	push fs
98	pop es
99	pop si
100	pop cx
101	loop .drawpixelrow
102
103	.error:
104	pop es
105	ret
106
107	;
108	; rledecode:
109	; Decode a pixel row in RLE16 format.
110	;
111	; FS:SI -> input
112	; CX -> pixel count
113	; ES:DI -> output (packed pixel)
114	;
115	rledecode:
116	shl esi,1 ; Nybble pointer
117	xor dl,dl ; Last pixel
118	.loop:
119	call .getnybble
120	cmp al,dl
121	je .run ; Start of run sequence
122	stosb
123	mov dl,al
124	dec cx
125	jnz .loop
126	.done:
127	shr esi,1
128	adc si,byte 0
129	ret
130	.run:
131	xor bx,bx
132	call .getnybble
133	and al,al
134	jz .longrun
135	mov bl,al
136	.dorun:
137	push cx
138	mov cx,bx
139	mov al,dl
140	rep stosb
141	pop cx
142	sub cx,bx
143	ja .loop
144	jmp short .done
145	.longrun:
146	call .getnybble
147	mov ah,al
148	call .getnybble
149	shl al,4
150	or al,ah
151	mov bl,al
152	add bx,16
153	jmp short .dorun
154	.getnybble:
155	shr esi,1
156	fs lodsb
157	jc .high
158	dec si
159	and al,0Fh
160	stc
161	rcl esi,1
162	ret
163	.high:
164	shr al,4
165	cmp si,xbs_vgabuf+trackbufsize ; Chunk overrun
166	jb .nonewchunk
167	call vgagetchunk
168	mov si,xbs_vgabuf ; Start at beginning of buffer
169	.nonewchunk:
170	shl esi,1
171	ret
172
173	;
174	; vgagetchunk:
175	; Get a new trackbufsize chunk of VGA image data
176	;
177	; On input, ES is assumed to point to the buffer segment.
178	;
179	vgagetchunk:
180	pushad
181	mov si,[VGACluster]
182	and si,si
183	jz .eof ; EOF overrun, not much to do...
184
185	mov cx,[BufSafe] ; One trackbuf worth of data
186	mov bx,xbs_vgabuf
187	call getfssec
188
189	jnc .noteof
190	xor si,si
191	.noteof: mov [VGACluster],si
192
193	.eof: popad
194	ret
195
196	;
197	; packedpixel2vga:
198	; Convert packed-pixel to VGA bitplanes
199	;
200	; FS:SI -> packed pixel string
201	; BP -> pixel count (multiple of 8)
202	; ES:DI -> output
203	;
204	packedpixel2vga:
205	mov dx,3C4h ; VGA Sequencer Register select port
206	mov al,2 ; Sequencer mask
207	out dx,al ; Select the sequencer mask
208	inc dx ; VGA Sequencer Register data port
209	mov al,1
210	mov bl,al
211	.planeloop:
212	pusha
213	out dx,al
214	.loop1:
215	mov cx,8
216	.loop2:
217	xchg cx,bx
218	fs lodsb
219	shr al,cl
220	rcl ch,1 ; VGA is bigendian. Sigh.
221	xchg cx,bx
222	loop .loop2
223	mov al,bh
224	stosb
225	sub bp,byte 8
226	ja .loop1
227	popa
228	inc bl
229	shl al,1
230	cmp bl,4
231	jbe .planeloop
232	ret
233
234	;
235	; vgasetmode:
236	; Enable VGA graphics, if possible; return ZF=1 on success
237	; DS must be set to the base segment; ES is set to DS.
238	;
239	vgasetmode:
240	push ds
241	pop es
242	mov ax,1A00h ; Get video card and monitor
243	xor bx,bx
244	int 10h
245	sub bl, 7 ; BL=07h and BL=08h OK
246	cmp bl, 1
247	ja .error ; ZF=0
248	; mov bx,TextColorReg
249	; mov dx,1009h ; Read color registers
250	; int 10h
251	mov ax,0012h ; Set mode = 640x480 VGA 16 colors
252	int 10h
253	mov dx,linear_color
254	mov ax,1002h ; Write color registers
255	int 10h
256	mov [UsingVGA], byte 1
257
258	call use_font ; Set graphics font/data
259	mov byte [ScrollAttribute], 00h
260
261	xor ax,ax ; Set ZF
262	.error:
263	ret
264
265	;
266	; vgaclearmode:
267	; Disable VGA graphics. It is not safe to assume any value
268	; for DS or ES.
269	;
270	vgaclearmode:
271	push ds
272	push es
273	pushad
274	mov ax,cs
275	mov ds,ax
276	mov es,ax
277	cmp [UsingVGA], byte 1
278	jne .done
279	mov ax,0003h ; Return to normal video mode
280	int 10h
281	; mov dx,TextColorReg ; Restore color registers
282	; mov ax,1002h
283	; int 10h
284	mov [UsingVGA], byte 0
285
286	call use_font ; Restore text font/data
287	mov byte [ScrollAttribute], 07h
288	.done:
289	popad
290	pop es
291	pop ds
292	ret
293
294	;
295	; vgashowcursor/vgahidecursor:
296	; If VGA graphics is enabled, draw a cursor/clear a cursor
297	;
298	vgashowcursor:
299	pushad
300	mov al,'_'
301	jmp short vgacursorcommon
302	vgahidecursor:
303	pushad
304	mov al,' '
305	vgacursorcommon:
306	cmp [UsingVGA], byte 1
307	jne .done
308	mov ah,09h
309	mov bx,0007h
310	mov cx,1
311	int 10h
312	.done:
313	popad
314	ret
315
316
317	section .data
318	; Map colors to consecutive DAC registers
319	linear_color db 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 0
320	UsingVGA db 0
321
322	section .latebss
323	alignb 2
324	GraphXSize resw 1 ; Width of splash screen file
325	VGAPos resw 1 ; Pointer into VGA memory
326	VGACluster resw 1 ; Cluster pointer for VGA image file
327	VGAFilePtr resw 1 ; Pointer into VGAFileBuf
328	TextColorReg resb 17 ; VGA color registers for text mode
329	%if IS_SYSLINUX
330	VGAFileBuf resb FILENAME_MAX+2 ; Unmangled VGA image name
331	%else
332	VGAFileBuf resb FILENAME_MAX ; Unmangled VGA image name
333	%endif
334	VGAFileBufEnd equ $
335	VGAFileMBuf resb FILENAME_MAX ; Mangled VGA image name
336